Fonction Excel : REGEX.REMPLACER

La fonction REGEX.REMPLACER remplace une ou plusieurs parties d'un texte en fonction d'une expression régulière.

Utilisation :

=REGEX.REMPLACER(texte; regex; remplacement)

ou :

=REGEX.REMPLACER(texte; regex; remplacement; occurrence; casse)

Si vous ne savez pas ce qu'est une expression régulière ou si vous ne savez pas comment en écrire une, commencez tout d'abord par le tutoriel complet qui accompagne la fonction REGEX.TEST avant de poursuivre.

Remplacement simple

La fonction REGEX.REMPLACER remplace ici le mot "amusant" par le mot "drôle" :

=REGEX.REMPLACER(A2;"amusant";"drôle")

excel fonction regex remplacer mot

Le problème avec cette formule est que si le texte contient le mot "amusante" (avec un "e"), il sera remplacé par "drôlee" (comme vous pouvez le voir dans la cellule colorée).

Pour éviter ce problème, il faut indiquer que "amusant" peut être suivi ou non par un "e" :

=REGEX.REMPLACER(A2;"amusante?";"drôle")

excel fonction regex remplacer mots

Suppression de caractères

Pour supprimer tous les caractères non numériques (et conserver ici uniquement le numéro de téléphone), entrez la regex "\D" et remplacez ces caractères par une chaîne vide "" :

=REGEX.REMPLACER(A2;"\D";"")

excel fonction regex remplacer numeros telephone

Extraire les domaines

La formule suivante supprime tous les caractères jusqu'au "@" pour obtenir uniquement les domaines des adresses email :

=REGEX.REMPLACER(A2;".*@";"")

excel fonction regex remplacer extraire email domaine

Pour extraire uniquement le nom du domaine sans l'extension, la formule devient alors :

=REGEX.REMPLACER(A2;".*@|\.[a-z]+";"")

excel fonction regex remplacer extraire domaine

Modifier le format de dates

La formule suivante convertit les dates au format US (année/mois/jour) vers le format EU (jour/mois/année) :

=REGEX.REMPLACER(A2;"(20\d{2})\W([0-1]?\d)\W([0-3]?\d)";"$3/$2/$1")

$1 retourne la valeur de la première paire de parenthèses, $2 retourne la valeur de la seconde paire de parenthèses, etc.

Pour valider cette regex la date (qui est ici au format texte) doit :

(20\d{2}) : commencer par un nombre entre 2000 et 2099 (parenthèses = $1 dans la valeur de remplacement)
\W : être suivi par un caractère non alphanumérique
([0-1]?\d) : être suivi par 1 ou 2 chiffres (parenthèses = $2 dans la valeur de remplacement)
\W : être suivi par un caractère non alphanumérique
([0-3]?\d) : être suivi par 1 ou 2 chiffres (parenthèses = $3 dans la valeur de remplacement)

excel fonction regex remplacer format date

Autres arguments

Vous pouvez préciser le numéro de l'occurrence à remplacer en troisième argument (par défaut 0, toutes). Pour compter à partir de la fin, entrez une valeur négative.

Pour ne pas tenir compte de la casse, entrez la valeur 1 en quatrième argument de la fonction (par défaut 0, tient compte de la casse).

Par exemple, la formule suivante remplace uniquement la deuxième occurrence et ne tient pas compte de la casse :

=REGEX.REMPLACER(A2;"tableurs?";"EXCEL";2;1)

excel fonction regex remplacer occurrence casse